PRIMEIRA RESPOSTA PARA A 2ª QUESTÃO DA PROVA PARCIAL TIPO03

//2ª Questão Prova Parcia FAMA
//Em um restaurante, uma tulipa de chopp custa R$ 2,50 e um tira gosto grande custa R$27,00 mais R$1,50 por tipo de ingredientes pedido (queijo, presunto, azeitona, etc.).
//Uma turma vai ao barzinho e pede uma determinada quantidade de "chopps" e uma quantidade de tira gosto grande com uma determinada quantidade de ingredientes em cada.
//Faça um algoritmo em VisuAlg que calcule e exiba a conta, (se o pagamento for a vista o cliente terá um desconto de 20%,se o pagamento for em cartão de crédito o desconto é de 10%, se for em cheque não terá desconto) sabendo-se quantas pessoas estão à mesa, mostre também quanto cada um deve pagar. (não esqueça os 10% do garçom que não entra no calculo do desconto e é sobre o valor total)

Algoritmo "2ª Questão"
// Disciplina   : ALGORITMOS
// Professor    : ANGELO DA CUNHA SÁ
// Descrição   : Calculo de Conta no Restaurante
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 13/09/2016
Var
   // Seção de Declarações das variáveis
   QTDCHOPP,QTDTIRAGOSTO,QTDINGREDIENTES:INTEIRO
   FORMAPAG:INTEIRO
   CONTATOTAL,GORJETA,CONTAFINAL,DESCONTO,QTDPESSOAS,VALPESSOA:REAL
   CONTAAPAGAR:REAL
Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   ESCREVAL("¦TULIPA DE CHOPP - R$2,50                                ¦")
   ESCREVAL("¦TIRA GOSTO - R$27,00 MAIS R$1,50 POR INGREDIENTE PEDIDO ¦")
   ESCREVAL("¦ATENÇÃO: COBRAMOS 10% DE GORJETA PARA O GARÇOM          ¦")
   ESCREVAL("¦OBS: o valor dos 10% é sobre o valor total da conta     ¦")
   ESCREVAL("¦FORMAS DE PAGAMENTO                                     ¦")
   ESCREVAL("¦1 - PAGAMENTO À VISTA - &&&& 20% DE DESCONTO            ¦")
   ESCREVAL("¦2 - PAGAMENTO CARTÃO DE CRÉDITO - &&&& 10% DE DESCONTO  ¦")
   ESCREVAL("¦3 - ACEITAMOS CHEQUES - NÃO DAMOS DESCONTO              ¦")
   ESCREVAL("QUANTAS TULIPAS DE CHOPP, VOCÊS DESEJAM?")
   LEIA(QTDCHOPP)
   ESCREVAL("QUANTOS TIRA-GOSTO?")
   LEIA(QTDTIRAGOSTO)
   ESCREVAL("QUAIS INGREDIENTES?")
   LEIA(QTDINGREDIENTES)
   ESCREVAL("QUANTAS PESSOAS ESTÃO NA MESA PARA DIVIDIR A CONTA?")
   LEIA(QTDPESSOAS)
   ESCREVAL("QUAL A SUA FORMA DE PAGAMENTO?")
   LEIA(FORMAPAG)
   CONTATOTAL<-QTDCHOPP*2.5+QTDTIRAGOSTO*27+QTDINGREDIENTES*1.5
   GORJETA<-CONTATOTAL*0.1
   CONTAFINAL<-CONTATOTAL+GORJETA
   SE FORMAPAG=1 ENTAO
      DESCONTO<-CONTATOTAL*0.2
      CONTAAPAGAR<-CONTATOTAL-DESCONTO+GORJETA
   SENAO
      SE FORMAPAG=2 ENTAO
         DESCONTO<-CONTATOTAL*0.1
         CONTAAPAGAR<-CONTATOTAL-DESCONTO+GORJETA
      SENAO
         SE FORMAPAG=3 ENTAO
            CONTAAPAGAR<-CONTAFINAL
            ESCREVAL("SEU PAGAMENTO É EM CHEQUE")
            ESCREVAL("VOCÊ NÃO TERÁ DESCONTO")
         SENAO
            ESCREVAL("OPÇÃO DE PAGAMENTO INVÁLIDA")
         FIMSE
      FIMSE
   FIMSE
   VALPESSOA<-CONTAAPAGAR/QTDPESSOAS
   ESCREVAL("PREZADO CLIENTE SUA CONTA É NO TOTAL DE: R$",CONTAFINAL:4:2)
   ESCREVAL("SENDO QUE DESSE VALOR, O TOTAL DA GORJETA É DE: R$",GORJETA:4:2)
   ESCREVAL("O VALOR DO DESCONTO FOI DE: R$",DESCONTO:4:2)
   ESCREVAL("O VALOR DA CONTA A SER PAGO É : R$",CONTAAPAGAR:4:2)
   ESCREVAL("O VALOR A SER PAGO POR CADA UM É: R$",VALPESSOA:4:2)



Fimalgoritmo